;; CADLisp Tools - Drawing Layer Checker (read-only)
(defun ct-lc:layer-count (name / ss)
  (if (setq ss (ssget "_X" (list (cons 8 name)))) (sslength ss) 0))

(defun c:LAYERCHECK (/ color flags name row)
  (prompt (strcat "\nObjects on Layer 0 (all layouts): " (itoa (ct-lc:layer-count "0"))))
  (prompt (strcat "\nObjects on Defpoints (all layouts): " (itoa (ct-lc:layer-count "Defpoints"))))
  (prompt "\n--- Layers with special states ---")
  (setq row (tblnext "LAYER" T))
  (while row
    (setq name (cdr (assoc 2 row)) flags (cdr (assoc 70 row)) color (cdr (assoc 62 row)))
    (if (or (and color (< color 0))
            (/= 0 (logand flags 1))
            (/= 0 (logand flags 4))
            (/= 0 (logand flags 16)))
      (prompt (strcat "\n" name
        (if (and color (< color 0)) " [off]" "")
        (if (/= 0 (logand flags 1)) " [frozen]" "")
        (if (/= 0 (logand flags 4)) " [locked]" "")
        (if (/= 0 (logand flags 16)) " [xref-dependent]" ""))))
    (setq row (tblnext "LAYER")))
  (princ))
